;;; -*- Mode: TDL; Coding: utf-8 -*- 

;;; Authors: 
;;; 1994 Hans-Ulrich Krieger
;;; 2007 Nicolai Kilian

;;; Copyright: DFKI GmbH


*undef* :< *sort*.

*rule* :=
   stem-or-sign &
   args-type.   

unary-rule_min := 
    *rule* & [ SIGNPUNCT.--COORDPAIRED #coordpaired,
	       MAL #m,
	       MALRULE [ MAL-NONLOC-VEND-BLEND #mal-nonloc-vend-blend,
			 MAL-DOUBLET #mal-doublet,
			 MAL-INFL #mal-infl ],
	       ARGS < [ SIGNPUNCT.--COORDPAIRED #coordpaired,
			RESTR-COLL.SPANNING-ONLY -,
			MAL #m,
			MALRULE [ MAL-NONLOC-VEND-BLEND #mal-nonloc-vend-blend,
				  MAL-DOUBLET #mal-doublet,
				  MAL-INFL #mal-infl ] ] >
  ]. 

inher-left-sister-paired-rule :=
  unary-rule_min &
  [ SIGNPUNCT.--LEFT_SISTER_PAIRED #lspaired,
    ARGS < [ SIGNPUNCT.--LEFT_SISTER_PAIRED #lspaired ] >
  ].   

unary-rule :=                      
  inher-left-sister-paired-rule.

binary-rule :=                     
    *rule*  & [ MAL #m,
		MALRULE #malrule,
    ARGS < [ MAL #m,
	     MALRULE #malrule ], [ MAL #m,
				   MALRULE #malrule ] >].        

inher-all-pnct-unary-rule := unary-rule &
			     [ SIGNPUNCT #signpunct,
			       SYNSEM.PUNCT #sspunct,
			       ARGS < [ SIGNPUNCT #signpunct,
					SYNSEM.PUNCT #sspunct ] > ].

ternary-rule :=
    *rule*  & [
    ARGS < [ ], [ ], [ ] > ].